Описание
DateCreated возвращает дату и время создания объекта или основной таблицы для объекта Recordset типа таблицы (только в рабочей области Microsoft Jet).
LastUpdated возвращает дату и время последнего изменения объекта или основной таблицы для объекта Recordset типа таблицы (только в рабочей области Microsoft Jet).

Значение
Возвращаемое значение имеет тип Variant (подтип Date/Time).

Замечания
Для объектов Recordset типа таблицы дата и время определяются по системным часам компьютера, на котором была создана или последний раз обновлена основная таблица. Для объектов других типов данных свойства DateCreated и LastUpdated возвращают дату и время создания или последнего обновления объекта. В многопользовательской среде разные пользователи во избежание разночтений должны загружать значения данных свойств непосредственно с одного сервера файлов.

Пример
Следующая программа демонстрирует применение свойств DateCreated и LastUpdated путем добавления нового объекта Field в существующий объект TableDef, а также путем создания нового объекта TableDef. Для выполнения данной процедуры требуется функция DateOutput.

Sub DateCreatedX()

	Dim dbsNorthwind As Database
	Dim tdfEmployees As TableDef
	Dim tdfNewTable As TableDef

	Set dbsNorthwind = OpenDatabase("Борей.mdb")

	With dbsNorthwind
		Set tdfEmployees = .TableDefs!Сотрудники

		With tdfEmployees
			' Печатает текущие сведения о таблице "Сотрудники".
			DateOutput "Текущие свойства", tdfEmployees
			' Создает и добавляет поле в таблицу "Сотрудники".
			.Fields.Append .CreateField("НовоеПоле", dbDate)
			' Печатает новые сведения о таблице "Сотрудники".
			DateOutput "После создания нового поля", tdfEmployees
			' Удаляет новое поле, созданное только для демонстрации.
			.Fields.Delete "НовоеПоле"
		End With

		' Создает и добавляет новый объект TableDef 
		' в базу данных "Борей".
		Set tdfNewTable = .CreateTableDef("НоваяТаблица")
		With tdfNewTable
			.Fields.Append .CreateField("НовоеПоле", dbDate)
		End With
		.TableDefs.Append tdfNewTable

		' Печатает сведения о новом объекте TableDef.
		DateOutput "После создания новой таблицы", tdfNewTable

		' Удаляет новый объект TableDef, созданный 
		' только для демонстрации.
		.TableDefs.Delete tdfNewTable.Name
		.Close
	End With

End Sub

Function DateOutput(strTemp As String, 	tdfTemp As TableDef)

	' Печатает значения свойств DateCreated и LastUpdated
	' для указанного объекта TableDef.
	Debug.Print strTemp
	Debug.Print "    TableDef: " & tdfTemp.Name
	Debug.Print "        DateCreated = " & 	tdfTemp.DateCreated
	Debug.Print "        LastUpdated = " & 	tdfTemp.LastUpdated
	Debug.Print

End Function